gap> G := SymmetricGroup( 3 );;
gap> CG := GroupAsCategory( G );;
gap> u := GroupAsCategoryUniqueObject( CG );;
gap> SetOfObjects( CG ) = [ u ];
true
gap> SetOfGeneratingMorphisms( CG );
[ <(1,2,3)>, <(1,2)> ]
gap> Length( SetOfMorphismsOfFiniteCategory( CG ) ) = Size( G );
true
gap> x := (2,3) / CG;;
gap> id := () / CG;;
gap> x * x = id;
true
gap> IsIdenticalObj( x * x, id );
false
gap> alpha := GroupAsCategoryMorphism( CG, (1,2,3) );;
gap> alpha * Inverse( alpha ) = IdentityMorphism( u );
true
gap> beta := GroupAsCategoryMorphism( CG, (1,2,3,5) );;
gap> IsWellDefined( beta );
false
gap> gamma := GroupAsCategoryMorphism( CG, (1,3) );;
gap> IsWellDefined( gamma );
true
gap> Lift( alpha, gamma ) * gamma = alpha;
true
gap> alpha * Colift( alpha, gamma ) = gamma;
true
#@if IsPackageMarkedForLoading( "FinSetsForCAP", ">= 2023.07-03" )
gap> Length( HomomorphismStructureOnObjects( u, u ) ) = Size( G );
true
gap> InterpretMorphismFromDistinguishedObjectToHomomorphismStructureAsMorphism(
>         u,u,
>         PreCompose(
>                 InterpretMorphismAsMorphismFromDistinguishedObjectToHomomorphismStructure( alpha ),
>                 HomomorphismStructureOnMorphisms( gamma, Inverse( gamma ) ) ) )
> =
> gamma * alpha * Inverse( gamma );
true
#@fi