gap> LoadPackage( "ZariskiFrames", false );
true
gap> zz := HomalgRingOfIntegersInSingular( );
Z
gap> AffAlg_Z := CategoryOfAffineAlgebras( zz );
CategoryOfAffineAlgebras( Z )
gap> Display( AffAlg_Z );
A CAP category with name CategoryOfAffineAlgebras( Z ):

27 primitive operations were used to derive 154 operations for this category \
which algorithmically
* IsFiniteCocompleteCategory
* IsSymmetricMonoidalCategory
* IsCodistributiveCategory
and furthermore mathematically
* IsSymmetricMonoidalCategoryStructureGivenByCoproduct
gap> AffSch_Z := Opposite( AffAlg_Z : only_primitive_operations := true );
Opposite( CategoryOfAffineAlgebras( Z ) )
gap> Display( AffSch_Z );
A CAP category with name Opposite( CategoryOfAffineAlgebras( Z ) ):

27 primitive operations were used to derive 160 operations for this category \
which algorithmically
* IsFiniteCompleteCategory
* IsSymmetricMonoidalCategory
* IsDistributiveCategory
and furthermore mathematically
* IsSymmetricMonoidalCategoryStructureGivenByDirectProduct
gap> iota := UniversalMorphismFromInitialObject( TerminalObject( AffAlg_Z ) );
<A morphism in CategoryOfAffineAlgebras( Z )>
gap> Display( iota );
Z/( 1 )
  ^
  |
[  ]
  |
  |
Z/( 0 )
gap> IsWellDefined( iota );
true
gap> terminal := Source( iota );
<An object in CategoryOfAffineAlgebras( Z )>
gap> Dimension( terminal );
1
gap> initial := Target( iota );
<An object in CategoryOfAffineAlgebras( Z )>
gap> Dimension( initial );
-1
gap> uniq := UniversalMorphismIntoTerminalObject( InitialObject( AffAlg_Z ) );
<A morphism in CategoryOfAffineAlgebras( Z )>
gap> Display( uniq );
Z/( 1 )
  ^
  |
[  ]
  |
  |
Z/( 0 )
gap> IsWellDefined( uniq );
true
gap> iota = uniq;
true
gap> W := ( zz["e"] / "e^2-e" ) / AffAlg_Z;
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( W );
Z[e]/( e^2-e )
gap> Dimension( W );
1
gap> IsWellDefined( W );
true
gap> S := zz["x,y,z"] / AffAlg_Z;
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( S );
Z[x,y,z]/( 0 )
gap> Dimension( S );
4
gap> IsWellDefined( S );
true
gap> T := zz["u"] / AffAlg_Z;
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( T );
Z[u]/( 0 )
gap> Dimension( T );
2
gap> IsWellDefined( T );
true
gap> ExportVariables( ObjectDatum( T )[1] );
[ u ]
gap> phi := MorphismConstructor( S, [ u, u^2, u^3 ], T );
<A morphism in CategoryOfAffineAlgebras( Z )>
gap> Display( phi );
Z[u]/( 0 )
  ^
  |
[ |[ u ]|, |[ u^2 ]|, |[ u^3 ]| ]
  |
  |
Z[x,y,z]/( 0 )
gap> IsWellDefined( phi );
true
gap> coimage := CoimageObject( phi );
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( coimage );
Z[x,y,z]/( y^2-x*z, x*y-z, x^2-y )
gap> Dimension( coimage );
2
gap> IsWellDefined( coimage );
true
gap> prj := CoimageProjection( phi );
<A morphism in CategoryOfAffineAlgebras( Z )>
gap> Display( prj );
Z[x,y,z]/( y^2-x*z, x*y-z, x^2-y )
  ^
  |
[ |[ x ]|, |[ y ]|, |[ z ]| ]
  |
  |
Z[x,y,z]/( 0 )
gap> IsWellDefined( prj );
true
gap> IsEpimorphism( prj );
true
gap> IsMonomorphism( prj );
false
gap> ast := AstrictionToCoimage( phi );
<A morphism in CategoryOfAffineAlgebras( Z )>
gap> Display( ast );
Z[u]/( 0 )
  ^
  |
[ |[ u ]|, |[ u^2 ]|, |[ u^3 ]| ]
  |
  |
Z[x,y,z]/( y^2-x*z, x*y-z, x^2-y )
gap> IsWellDefined( ast );
true
gap> IsIsomorphism( ast );
true
gap> inv := InverseForMorphisms( ast );
<An isomorphism in CategoryOfAffineAlgebras( Z )>
gap> Display( inv );
Z[x,y,z]/( y^2-x*z, x*y-z, x^2-y )
  ^
  |
[ |[ x ]| ]
  |
  |
Z[u]/( 0 )
gap> IsWellDefined( inv );
true
gap> IsOne( PreCompose( ast, inv ) );
true
gap> IsOne( PreCompose( inv, ast ) );
true
gap> chi := MorphismConstructor( S, [ u^2, u^3, u^4 ], T );
<A morphism in CategoryOfAffineAlgebras( Z )>
gap> Display( chi );
Z[u]/( 0 )
  ^
  |
[ |[ u^2 ]|, |[ u^3 ]|, |[ u^4 ]| ]
  |
  |
Z[x,y,z]/( 0 )
gap> IsWellDefined( chi );
true
gap> coeq := Coequalizer( phi, chi );
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( coeq );
Z[u]/( -u^2+u, -u^3+u^2, -u^4+u^3 )
gap> Dimension( coeq );
1
gap> Display( coeq );
Z[u]/( u^2-u )
gap> pi := ProjectionOntoCoequalizer( [ phi, chi ] );
<An epimorphism in CategoryOfAffineAlgebras( Z )>
gap> IsOne( UniversalMorphismFromCoequalizer( [ phi, chi ], pi ) );
true
gap> P := DirectProduct( coimage, coeq );
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( P );
Z[c1,c2,c3,c4,c5,c6]/( c2^2-c1*c3, c1*c2-c3, c1^2-c2, -c5^2+c5, -c5^3+c5^2, \
-c5^4+c5^3, c4^2-c4, c6^2-c6, c4*c6, c1*c4-c1, c2*c4-c2, c3*c4-c3, c5*c6-c5, -c4-c6+1 )
gap> C := Coproduct( coimage, coeq );
<An object in CategoryOfAffineAlgebras( Z )>
gap> Display( C );
Z[c1,c2,c3,c4]/( c2^2-c1*c3, c1*c2-c3, c1^2-c2, -c4^2+c4, -c4^3+c4^2, \
-c4^4+c4^3 )
gap> C = TensorProduct( coimage, coeq );
true