GAP (GradedModulePresentationsForCAP) - Chapter 1: Graded Module Presentations

The GAP category of morphisms in the category of graded left or right presentations.

1.1-2 IsGradedLeftPresentationMorphism

1.1-3 IsGradedRightPresentationMorphism

1.1-4 IsGradedLeftOrRightPresentation

The GAP category of objects in the category of graded left presentations or graded right presentations.

1.1-5 IsGradedLeftPresentation

1.1-6 IsGradedRightPresentation

1.2 Constructors

1.2-1 GradedPresentationMorphism

The arguments are an object \(A\), a homalg matrix \(M\), and another object \(B\). \(A\) and \(B\) shall either both be objects in the category of graded left presentations or both be objects in the category of graded right presentations. The output is a morphism \(A \rightarrow B\) in the the category of graded left or right presentations whose underlying matrix is given by \(M\).

1.2-2 AsGradedLeftPresentation

The argument is a homalg matrix \(M\) over a graded ring \(R\). The output is an object in the category of graded left presentations over \(R\). This object has \(M\) as its underlying matrix.

1.2-3 AsGradedRightPresentation

The argument is a homalg matrix \(M\) over a ring \(R\). The output is an object in the category of right presentations over \(R\). This object has \(M\) as its underlying matrix.

1.2-4 AsGradedLeftOrRightPresentation

The arguments are a homalg matrix \(M\) and a boolean \(l\). If \(l\) is true, the output is an object in the category of left presentations. If \(l\) is false, the output is an object in the category of right presentations. In both cases, the underlying matrix of the result is \(M\).

1.2-5 GradedFreeLeftPresentation

The arguments are a non-negative integer \(r\) and a graded homalg ring \(R\). The output is an object in the category of graded left presentations over \(R\). It is represented by the \(0 \times r\) matrix and thus it is free of rank \(r\).

1.2-6 GradedFreeRightPresentation

The arguments are a non-negative integer \(r\) and a graded homalg ring \(R\). The output is an object in the category of graded right presentations over \(R\). It is represented by the \(r \times 0\) matrix and thus it is free of rank \(r\).

1.2-7 UnderlyingPresentationObject

The argument is an object \(A\) in the category of graded left or right presentations over a homalg ring \(R\). The output is the corresponding object in the category of left or right presentations.

1.2-8 UnderlyingHomalgRing

The argument is an object \(A\) in the category of graded left or right presentations over a homalg ring \(R\). The output is \(R\).

1.2-9 GeneratorDegrees

The argument is an object \(A\) in the category of graded left of right presentations over a ring \(R\). The output is a list of elements of the degree group of \(R\), the weights of the generators of \(A\).

1.2-10 AffineDimension

Returns the Krull dimension (of the annihilator ideal) of the underlying nongraded module A. The underlying ring must be commutative.

1.2-11 GradedLeftPresentations

The argument is a graded homalg ring \(R\). The output is the category of graded left presentations over \(R\).

1.2-12 GradedRightPresentations

The argument is a graded homalg ring \(R\). The output is the category of graded right presentations over \(R\).

1.3 Attributes

1.3-1 UnderlyingHomalgRing

The argument is a morphism \(\alpha\) in the category of left or right presentations over a homalg ring \(R\). The output is \(R\).

1.3-2 UnderlyingMatrix

The argument is a morphism \(\alpha\) in the category of left or right presentations. The output is its underlying homalg matrix.

1.4 Non-Categorical Operations

1.4-1 StandardGeneratorMorphism

The argument is an object \(A\) in the category of left or right presentations over a homalg ring \(R\) with underlying matrix \(M\) and an integer \(i\). The output is a morphism \(F \rightarrow A\) given by the \(i\)-th row or column of \(M\), where \(F\) is a free left or right presentation of rank \(1\).

1.4-2 CoverByProjective

The argument is an object \(A\) in the category of left or right presentations. The output is a morphism from a free module \(F\) to \(A\), which maps the standard generators of the free module to the generators of \(A\).

1.5 Examples

gap> LoadPackage( "GradedModulePresentationsForCAP" );
true
gap> Q := HomalgFieldOfRationalsInSingular( );
Q
gap> S := GradedRing( Q["x,y"] );
Q[x,y]
(weights: yet unset)
gap> Sgrmod := GradedLeftPresentations( S );
The category of graded left f.p. modules over Q[x,y] (with weights [ 1, 1 ])
gap> Display( Sgrmod );
A CAP category with name
The category of graded left f.p. modules over Q[x,y] (with weights [ 1, 1 ]):

38 primitive operations were used to derive 228 operations for this category
which algorithmically
* IsMonoidalCategory
* IsAbelianCategoryWithEnoughProjectives
and not yet algorithmically
* IsSymmetricClosedMonoidalCategory
gap> #ListPrimitivelyInstalledOperationsOfCategory( Sgrmod );
gap> M := GradedFreeLeftPresentation( 2, S, [ 1, 1 ] );
<An object in The category of graded left f.p. modules over Q[x,y]
 (with weights [ 1, 1 ])>
gap> N := GradedFreeLeftPresentation( 1, S, [ 0 ] );
<An object in The category of graded left f.p. modules over Q[x,y]
 (with weights [ 1, 1 ])>
gap> mat := HomalgMatrix( "[x,y]", 2, 1, S );
<A 2 x 1 matrix over a graded ring>
gap> Display( mat );
x,
y
(over a graded ring)
gap> phi := GradedPresentationMorphism( M, mat, N );
<A morphism in The category of graded left f.p. modules over Q[x,y]
 (with weights [ 1, 1 ])>
gap> IsWellDefined( phi );
true
gap> IsMonomorphism( phi );
false
gap> IsEpimorphism( phi );
false
gap> iota := ImageEmbedding( phi );
<A monomorphism in The category of graded left f.p. modules over Q[x,y]
 (with weights [ 1, 1 ])>
gap> IsMonomorphism( iota );
true
gap> IsIsomorphism( iota );
false
gap> coker_mod := CokernelObject( phi );
<An object in The category of graded left f.p. modules over Q[x,y]
 (with weights [ 1, 1 ])>
gap> Display( coker_mod );
x,
y
(over a graded ring)

An object in The category of graded left f.p. modules over Q[x,y]
(with weights [ 1, 1 ])

(graded, degree of generator:[ 0 ])
gap> IsZero( coker_mod );
false
gap> is_artinian := M -> AffineDimension( M ) <= 0;
function( M ) ... end
gap> C := FullSubcategoryByMembershipFunction( Sgrmod, is_artinian );
<Subcategory of The category of graded left f.p. modules over Q[x,y]
 (with weights [ 1, 1 ]) by is_artinian>
gap> CohP1 := Sgrmod / C;
The Serre quotient category of The category of graded left f.p. modules
over Q[x,y] (with weights [ 1, 1 ]) by test function with name: is_artinian
gap> Display( CohP1 );
A CAP category with name
The Serre quotient category of The category of graded left f.p. modules
over Q[x,y] (with weights [ 1, 1 ]) by test function with name: is_artinian:

21 primitive operations were used to derive 187 operations for this category
which algorithmically
* IsAbelianCategory
gap> Sh := CanonicalProjection( CohP1 );
Localization functor of The Serre quotient category of The category of graded left
f.p. modules over Q[x,y] (with weights [ 1, 1 ]) by test function with name:
is_artinian
gap> InstallFunctor( Sh, "Sheafification" );
gap> psi := ApplyFunctor( Sh, phi );
<A morphism in The Serre quotient category of The category of graded left
 f.p. modules over Q[x,y] (with weights [ 1, 1 ]) by test function with name:
 is_artinian>
gap> IsMonomorphism( psi );
false
gap> IsEpimorphism( psi );
true
gap> coker_shv := CokernelObject( psi );
<A zero object in The Serre quotient category of The category of graded left
 f.p. modules over Q[x,y] (with weights [ 1, 1 ]) by test function with name:
 is_artinian>
gap> IsZero( coker_shv );
true
gap> epsilon := ApplyFunctor( Sh, iota );
<A morphism in The Serre quotient category of The category of graded left
 f.p. modules over Q[x,y] (with weights [ 1, 1 ]) by test function with name:
 is_artinian>
gap> IsIsomorphism( epsilon );
true

1 Graded Module Presentations

1.1 GAP Categories

1.1-1 IsGradedLeftOrRightPresentationMorphism